CMAKE_MINIMUM_REQUIRED(VERSION 3.16)
set(CMAKE_OSX_DEPLOYMENT_TARGET "15" CACHE STRING "Minimum OS X deployment version")
project(dxirc-all)
set(PROJECT_VERSION "1.50.0")

set(CMAKE_CXX_STANDARD 17)
set(CMAKE_CXX_STANDARD_REQUIRED ON)

list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/cmake")

find_package(PkgConfig)
find_package(Libintl)
find_package(Gettext)

# Enable i10n.
if(LIBINTL_LIB_FOUND)
    set(ENABLE_NLS TRUE)
endif(LIBINTL_LIB_FOUND)

if(NOT WIN32)
    option(USE_ENCHANT "Enable spellchecking" FALSE)
else(NOT WIN32)
    option(USE_ENCHANT "Enable spellchecking" TRUE)
endif(NOT WIN32)

if(APPLE)
option(ENABLE_OSX_BUNDLE "Package dxirc as an OSX bundle (ignored on other platforms)." OFF)
endif(APPLE)

set(HAVE_LUA FALSE)
find_package(Lua)
# Headers and library must be the same Lua version. After a distro upgrade
# (e.g. Lua 5.4 -> 5.5) the cache can keep the old library while lua.h is new,
# then linking fails on luaL_openselectedlibs. Check and retry with fresh library.
include(CheckCXXSourceCompiles)
function(dxirc_check_lua result)
    set(CMAKE_REQUIRED_INCLUDES ${LUA_INCLUDE_DIR})
    set(CMAKE_REQUIRED_LIBRARIES ${LUA_LIBRARIES})
    set(CMAKE_REQUIRED_QUIET TRUE)
    unset(${result} CACHE)
    check_cxx_source_compiles("
extern \"C\" {
#include <lua.h>
#include <lualib.h>
#include <lauxlib.h>
}
int main() { lua_State *L = luaL_newstate(); luaL_openlibs(L); lua_close(L); return 0; }
" ${result})
    set(${result} ${${result}} PARENT_SCOPE)
endfunction()
# FindLua doesn't find Lua 5.5: it knows versions only up to 5.4 and lua.h 5.5 has
# the version in LUA_VERSION_*_N (LUA_VERSION_MAJOR is no longer a string literal)
set(DXIRC_LUA55 FALSE)
if(NOT LUA_FOUND)
    find_path(LUA55_INCLUDE_DIR lua.h
        HINTS ENV LUA_DIR
        PATH_SUFFIXES include/lua5.5 include/lua55 include/lua-5.5 include lua5.5 lua55 lua-5.5)
    if(LUA55_INCLUDE_DIR)
        file(STRINGS "${LUA55_INCLUDE_DIR}/lua.h" _lua_version_lines
            REGEX "^#define[ \t]+LUA_VERSION_(MAJOR|MINOR|RELEASE)_N[ \t]+[0-9]+")
        foreach(_part MAJOR MINOR RELEASE)
            set(_lua_${_part} "")
            foreach(_line IN LISTS _lua_version_lines)
                if(_line MATCHES "LUA_VERSION_${_part}_N[ \t]+([0-9]+)")
                    set(_lua_${_part} ${CMAKE_MATCH_1})
                endif()
            endforeach()
        endforeach()
        if("${_lua_MAJOR}.${_lua_MINOR}" STREQUAL "5.5")
            find_library(LUA55_LIBRARY
                NAMES lua5.5 lua55 lua-5.5 lua.5.5 lua
                NAMES_PER_DIR
                HINTS ENV LUA_DIR
                PATH_SUFFIXES lib)
            if(LUA55_LIBRARY)
                set(LUA_INCLUDE_DIR ${LUA55_INCLUDE_DIR})
                set(LUA_LIBRARY ${LUA55_LIBRARY})
                set(LUA_LIBRARIES ${LUA55_LIBRARY})
                if(UNIX AND NOT APPLE)
                    list(APPEND LUA_LIBRARIES m ${CMAKE_DL_LIBS})
                endif()
                set(LUA_VERSION_STRING "${_lua_MAJOR}.${_lua_MINOR}.${_lua_RELEASE}")
                set(LUA_FOUND TRUE)
                set(DXIRC_LUA55 TRUE)
                message(STATUS "Found Lua ${LUA_VERSION_STRING}: ${LUA_LIBRARY}")
            endif()
        endif()
    endif()
endif()
if(LUA_FOUND)
    dxirc_check_lua(LUA_WORKS)
    if(NOT LUA_WORKS AND NOT DXIRC_LUA55)
        message(STATUS "Lua ${LUA_VERSION_STRING} headers don't match ${LUA_LIBRARY}, searching library again")
        unset(LUA_LIBRARY CACHE)
        unset(LUA_MATH_LIBRARY CACHE)
        find_package(Lua)
        dxirc_check_lua(LUA_WORKS)
    endif()
    if(LUA_WORKS)
        set(HAVE_LUA TRUE)
    else()
        message(WARNING "Lua headers in ${LUA_INCLUDE_DIR} (${LUA_VERSION_STRING}) don't link with ${LUA_LIBRARIES}, building without lua. Set LUA_INCLUDE_DIR and LUA_LIBRARY to the same Lua version.")
    endif()
endif(LUA_FOUND)

if(APPLE AND ENABLE_OSX_BUNDLE)
    add_definitions(-DLOCALEDIR="./locale")
    add_definitions(-DDXIRC_DATADIR="/../Resources")
elseif(WIN32)
    add_definitions(-DLOCALEDIR="./locale")
    add_definitions(-DDXIRC_DATADIR=".")
else()
    add_definitions(-DLOCALEDIR="${CMAKE_INSTALL_PREFIX}/share/locale")
    add_definitions(-DDXIRC_DATADIR="${CMAKE_INSTALL_PREFIX}/share/dxirc")
endif()

if(CMAKE_BUILD_TYPE MATCHES Debug)
add_definitions(-DDEBUG)
endif(CMAKE_BUILD_TYPE MATCHES Debug)

if(NOT WIN32)
# Source distribution
set(ARCHIVE_NAME dxirc-${PROJECT_VERSION})
# committed HEAD only, paths with export-ignore in .gitattributes are left out
add_custom_target(dist COMMAND git -C ${CMAKE_CURRENT_SOURCE_DIR} archive
    --format=tar.gz --prefix=${ARCHIVE_NAME}/
    -o ${CMAKE_CURRENT_SOURCE_DIR}/${ARCHIVE_NAME}.tar.gz HEAD
)
endif(NOT WIN32)

if(APPLE)
    if(ENABLE_OSX_BUNDLE)
        set(BUILD_FOX FALSE)
        set(BUILD_QT TRUE)
    else()
        option(BUILD_FOX "Build dxirc with fox toolkit GUI" FALSE)
        option(BUILD_QT "Build dxirc with qt GUI" TRUE)
    endif(ENABLE_OSX_BUNDLE)
else()
option(BUILD_FOX "Build dxirc with fox toolkit GUI" TRUE)
option(BUILD_QT "Build dxirc with qt GUI" TRUE)
endif(APPLE)

option(DXIRC_BUILD_TESTS "Build tests (run with ctest)" OFF)
if(DXIRC_BUILD_TESTS)
    enable_testing()
endif()

add_subdirectory(data)
if(BUILD_FOX)
    add_subdirectory(fox)
endif(BUILD_FOX)
if(BUILD_QT)
    add_subdirectory(qt)
endif(BUILD_QT)

# uninstall target
configure_file(
    ${CMAKE_CURRENT_SOURCE_DIR}/cmake/uninstall.cmake.in
    ${CMAKE_CURRENT_BINARY_DIR}/cmake/uninstall.cmake
    IMMEDIATE @ONLY)
add_custom_target(uninstall
    ${CMAKE_COMMAND} -P ${CMAKE_CURRENT_BINARY_DIR}/cmake/uninstall.cmake)
